Julien Sopena

const
    TAILLE_MAX = 100 ;

type
    t_indice = 0..TAILLE_MAX ;
    t_bit = boolean;
    t_tabImage = array[t_indice, t_indice] of t_bit ;
    t_image = record
        tab : t_tabImage ;
        largeur : t_indice ;
        hauteur : t_indice ;
    end;

procedure lireImage(nomFichier : string ; var img : t_image);
var
    f : text;
    c : char;
    i, j: t_indice;
begin
    assign(f, nomFichier) ;
  reset(f);
    i := 0;
    while (not eof(f)) do
    begin
        i := i+1;
        j := 0;
        while (not eoln(f)) do
        begin
            j := j+1;
            read(f,c);
            img.tab[i,j] := c = '1';
        end ;
        read(f,c);
    end ;
    img.largeur := j;
    img.hauteur := i ;
    close(f);
end;

procedure afficheImage(img : t_image);
var
    i,j : t_indice;
begin
    for i := 1 to img.hauteur do
    begin
        for j := 1 to img.largeur do
            if img.tab[i,j] then
                write ('X')
            else 
                write (' ');
        writeln ;
    end;
end;

procedure ecrireImage(fichier : string ; img : t_image);
var
    f : text;
    i,j : t_indice;
begin
    assign(f, fichier) ;
    rewrite(f);
    for i := 1 to img.hauteur do
    begin
        for j := 1 to img.largeur do
            if img.tab[i,j] then
                write (f,'1')
            else 
                write (f,'0');
        writeln (f,'');
    end;
    close(f);
end;

procedure negatif(var img : t_image);
var
    i,j : t_indice;
begin
    for i := 1 to img.hauteur do
        for j := 1 to img.largeur do
            img.tab[i,j] :=  not img.tab[i,j] ;
end;

procedure erosion(var img : t_image);
var
    tmp : t_tabImage;
    i,j : t_indice;
begin
    tmp := img.tab ;
    for i := 2 to img.hauteur-1 do
        for j := 2 to img.largeur-1 do
            tmp[i,j] := img.tab[i,j] and 
                        img.tab[i-1,j-1] and
                        img.tab[i-1,j] and
                        img.tab[i-1,j+1] and
                        img.tab[i,j-1] and
                        img.tab[i,j+1] and
                        img.tab[i+1,j-1] and
                        img.tab[i+1,j] and
                        img.tab[i+1,j+1] ;
    img.tab := tmp ;
end;

procedure dilatation(var img : t_image);
var
    tmp : t_tabImage;
    i,j : t_indice;
begin
    tmp := img.tab ;
    for i := 2 to img.hauteur-1 do
        for j := 2 to img.largeur-1 do
            tmp[i,j] := img.tab[i,j] or
                        img.tab[i-1,j-1] or
                        img.tab[i-1,j] or
                        img.tab[i-1,j+1] or
                        img.tab[i,j-1] or
                        img.tab[i,j+1] or
                        img.tab[i+1,j-1] or
                        img.tab[i+1,j] or
                        img.tab[i+1,j+1] ;
    img.tab := tmp ;
end;

procedure supprimerBruit(var img : t_image);
var
    i,j : t_indice;
begin
    for i := 2 to img.hauteur-1 do
        for j := 2 to img.largeur-1 do
            img.tab[i,j] := img.tab[i,j] xor (
                                (img.tab[i-1,j-1] = not img.tab[i,j]) and
                                (img.tab[i-1,j] = not img.tab[i,j]) and
                                (img.tab[i-1,j+1] = not img.tab[i,j]) and
                                (img.tab[i,j-1] = not img.tab[i,j]) and
                                (img.tab[i,j+1] = not img.tab[i,j]) and
                                (img.tab[i+1,j-1] = not img.tab[i,j]) and
                                (img.tab[i+1,j] = not img.tab[i,j]) and
                                (img.tab[i+1,j+1] = not img.tab[i,j])
                                            )
end;

procedure ouverture(var img : t_image);
var
    tmp : t_tabImage;
    i,j : t_indice;
begin
    for i := 1 to img.hauteur do
        for j := 1 to img.largeur do
            tmp[i,j] := false;  
    for i := 1 to img.hauteur-1 do
        for j := 1 to img.largeur-1 do
            if img.tab[i,j] and img.tab[i,j+1] and img.tab[i+1,j] and img.tab[i+1,j+1] then
            begin
                tmp[i,j] := true ;
                tmp[i+1,j] := true ;
                tmp[i,j+1] := true ;
                tmp[i+1,j+1] := true ;
            end;    
    img.tab := tmp ;
end;

var 
    c : char ;
    s : string ;
    img : t_image ;

begin
    writeln ('Menu :');
    writeln ('  q->quitteri');
    writeln ('  l->lire');
    writeln ('  s->sauver');
    writeln ('  a->afficher');
    writeln ('  n->negatif');
    writeln ('  b->bruit');
    writeln ('  e->erosion');
    writeln ('  d->dilatation');
    writeln ('  o->ouverture');
    repeat
        write ('Entrer une action : ');
        readln (c);
        case c of
            'l' : begin
                write ('Entrer le nom du fichier a ouvrir : ');
                readln (s);
                lireImage(s,img);
            end;
            's' : begin
                write ('Entrer un nom pour enregistrer le fichier : ');
                readln (s); 
                ecrireImage(s,img);
            end;
            'a' : 
                afficheImage(img);
            'n' : 
                negatif(img);
            'b' : 
                supprimerBruit(img);
            'e' :
                erosion(img);
            'd' :
                dilatation(img);
            'o' :
                ouverture(img);
        end;
    until (c = 'q');
end.