Julien Sopena

const
    N_MAX = 10 ;

type
    t_indice = 1..N_MAX ;
    t_cMag = array[t_indice, t_indice] of word ;

procedure afficherCarreMagique(c : t_cMag; n:t_indice);
var
    i, j: t_indice;
begin
    for i:=1 to n do
    begin
        for j:=1 to n do
            write(c[i,j]:3,' ');
        writeln;
  end;
end;

function sommeLigne(c: t_cMag; n: t_indice; l: t_indice):word;
var
    j: t_indice;
    s: word;
begin
    s:=0;
    for j:=1 to n do
        s:=s+c[l,j];
    sommeLigne:=s;
end;

function sommeColonne(c: t_cMag; n:t_indice; col: t_indice): word;
var
    i: t_indice;
    s: word;
begin
    s:=0;
    for i:=1 to n do
        s:=s+c[i,col];
    sommeColonne:=s;
end;

function sommeDiag1(c: t_cMag; n: t_indice): word;
var
    i:t_indice;
    s:word;
begin
    s:=0;
    for i:=1 to n do
        s:=s+ c[i,i];
    sommeDiag1:=s;
end;

function sommeDiag2(c:t_cMag; n: t_indice):word;
var
    i:t_indice;
    s:word;
begin
    s:=0;
    for i:=1 to n do
        s:=s+ c[i,n-i+1];
    sommeDiag2:=s;
end;

function testCarreMagique(c:t_cMag; n:t_indice):boolean;
var
    valM: word;
    valid:boolean;
    i:t_indice;
begin
    valM:=n*(sqr(n)+1) div 2;
    valid:=(sommeDiag1(c,n)=valM) and (sommeDiag2(c,n)=valM);
    i:=1;
    while (valid) and  (i<=n) do
    begin
        valid:=(sommeLigne(c,n,i)=valM) and (sommeColonne(c,n,i)=valM);
        i:=i+1;
    end;
    testCarreMagique:=valid;
end;

function successeur (x : t_indice; n:t_indice) : t_indice ;
begin
    successeur := (x mod n) + 1;
end;

function predecesseur (x : t_indice; n:t_indice) : t_indice ;
begin
    if (x = 1) then
        predecesseur := n 
    else
        predecesseur := x - 1 ;
end;

procedure carreMagique (var c : t_cMag; n:t_indice);
var
    i,j:t_indice;
    k:word;
begin
    for i := 1 to n do
        for j := 1 to n do
            c[i,j]:=0;
    i := 1 ;
    j := (n div 2)+1;
    for k := 1 to sqr(n) do
    begin
        c[i,j]:=k;
        if c[predecesseur(i,n),successeur(j,n)] = 0 then
        begin
            i:= predecesseur(i,n);
            j:= predecesseur(j,n);
        end 
        else
            i:= successeur(i,n);
    end
end;

var 
    c : t_cMag;
    n : t_indice ;

begin
    repeat
        write ('Enrer la largeur du carre magique (entre 1 et ',N_MAX,') : ');
        readln (n);
    until (1<n) and (n<N_MAX);
    carreMagique(c,n);
    afficherCarreMagique(c,n);
    writeln;
    writeln('Le carre est-il magique ? ',testCarreMagique(c,n));
    readln;
end.